Ndtyjky

I'm using OpenGL to create a sphere (approximation):

I'm "inflating" the triangle to create an eight of a sphere:

I'm then drawing that octant four times, and each time rotating the model transoformation by 90°, to achieve a hemisphere:

Code related to drawing calls:

for (int i = 0; i < 4; i++) {

    model_trans = glm::rotate(model_trans, glm::radians(i * 90.0f), glm::vec3(0.0f, 0.0f, 1.0f));

    glUniformMatrix4fv(uniform_model, 1, GL_FALSE, glm::value_ptr(model_trans));

    glDrawElementsBaseVertex(GL_TRIANGLES, sizeof(sphere_indices) / sizeof(sphere_indices[0]),

                             GL_UNSIGNED_INT, 0, (sizeof(grid_vertices)) / (ATTR_COUNT * sizeof(GLfloat)));

}

My goal is to color each vertex based on the angle of its projection in the XY-plane. Since I'm normalizing values, the resulting projection should behave like an trigonometric circle, x value being the cosine value of the angle with the positive end of x-axis. And because the cosine is an continuous function, my sphere should have continual color, too. However, it is not so:

Is this issue caused by cloning the object? That's the only thing I can think of, but it shouldn't matter, since the vertex shader only receives individual vertices. Speaking of which, here is my vertex shader:

#version 150 core



in vec3 position;

/* flat : the color will be sourced from the provoking vertex. */

flat out vec3 Color;



/* transformation matrices */

uniform mat4 model;

uniform mat4 view;

uniform mat4 projection;



void main() {



    gl_Position = projection * view * model * vec4(position, 1.0);



    vec3 vector_proj = vec3(position.x, position.y, 0.0);

    normalize(vector_proj);

    /* Addition and division only for mapping range [-1, +1] to [0, 1] */

    float cosine = (vector_proj.x + 1) / 2;

    Color = vec3(cosine);

}

You want to calculate the color associated to the vertex from the world coordinate of the vertex position.

position is the model coordinate, but not the world coordinate. You have to apply the model matrix to position to transform from model space to world space, before calculating vector_proj:

vec4 world_pos = model * vec4(position, 1.0);



vec3 vector_proj = vec3( world_pos.xy, 0.0 );

The parameter to normalize is not an in-out parameter. It is an input parameter, the normalized result is returned from the function:

vector_proj = normalize(vector_proj);    

You can simplify the code as follows:

void main()

{

    vec4 world_pos = model * vec4(position, 1.0);

    gl_Position = projection * view * world_pos;



    vec2 vector_proj = normalize(world_pos.xy);



    /* Addition and division only for mapping range [-1, +1] to [0, 1] */

    float cosine = (vector_proj.x + 1) / 2;

    Color = vec3(cosine);

}