Ndtyjky

Let's say I have two arrays

A = {1, 2, 3}

and

B = {10,20,30,40,50}

I want to generate a new array which would have a size of

sizeof(A) * sizeof(B)

I want to replicate B sizeof(A) times, and on each repetition i, the resultant array should have A[i] added to it. So the result would be something like

{11,21,31,41,51,12,22,32,42,52,13,23,33,43,53}

This task can be interpreted as a 2-dimensional problem where the output array can be treated as a matrix of dimensions sizeof(A) times sizeof(B). In this way, we can use 2D CUDA indexing to achieve the desired functionality. A sample CUDA C++ code of this 2D implementation is shown below:

#include <iostream>

#include <cuda_runtime.h>

#include <cassert>



using namespace std;



__global__ void kernel_replicate(int* a, int* b, int* c, int alen, int blen, int clen)

{

    const int ai = blockIdx.x * blockDim.x + threadIdx.x;

    const int bi = blockIdx.y * blockDim.y + threadIdx.y;



    if(ai<alen && bi<blen)

    {

        const int ci = ai * blen + bi;

        c[ci] = a[ai] + b[bi];

    }

}





void replicate_device(int* a, int* b, int* c, int alen, int blen, int clen)

{

    dim3 block(16,16);

    dim3 grid;

    grid.x = (alen + block.x - 1) / block.x;

    grid.y = (blen + block.y - 1) / block.y;



    kernel_replicate<<<grid, block>>>(a,b,c,alen,blen,clen);



    assert(cudaSuccess == cudaDeviceSynchronize());

}





void replicate(int* a, int* b, int* c, int alen, int blen, int clen)

{

    int *ad, *bd, *cd;



    size_t abytes = alen * sizeof(int);

    size_t bbytes = blen * sizeof(int);

    size_t cbytes = clen * sizeof(int);



    cudaMalloc(&ad, abytes);

    cudaMalloc(&bd, bbytes);

    cudaMalloc(&cd, cbytes);



    cudaMemcpy(ad,a, abytes, cudaMemcpyHostToDevice);

    cudaMemcpy(bd,b, bbytes, cudaMemcpyHostToDevice);



    replicate_device(ad,bd,cd, alen,blen,clen);



    cudaMemcpy(c,cd, cbytes, cudaMemcpyDeviceToHost);





    cudaFree(ad);

    cudaFree(bd);

    cudaFree(cd);

}





int main()

{

    const int alen = 3;

    const int blen = 5;

    const int clen = alen * blen;



    int A[alen] = {1,2,3};

    int B[blen] = {10,20,30,40,50};

    int C[clen] = {0};



    replicate(A,B,C,alen, blen, clen);



    for(int i=0; i<alen; i++)

    {

        cout<<A[i]<<" ";

    }

    cout<<endl;



    for(int i=0; i<blen; i++)

    {

        cout<<B[i]<<" ";

    }

    cout<<endl;



    for(int i=0; i<clen; i++)

    {

        cout<<C[i]<<" ";

    }

    cout<<endl;





    return 0;

}