Ndtyjky

So I have a XML-File, which isn't formatted, meaning it only has one line. The problem I have is, I want to delete two lines or comment them out.

Is there a way to format the XML-file using a batch-script, so if i have:

<xml><tag><othertag></othertag></tag></xml>

the output would be

<xml>

     <tag>

          <othertag>

          </othertag>

     </tag>

</xml>

Alternatively, how can I replace/add Strings, when I only have a pattern, and can't use findstr /v, because I only have one line?

Thanks in advance!

@echo off

setlocal EnableDelayedExpansion



rem Create a variable with spaces

set "spaces= "

for /L %%i in (1,1,5) do set "spaces=!spaces!!spaces!"



rem Read the line

for /F "delims=" %%a in (input.txt) do set "line=%%a"



set level=0

:nextTag

   rem Separate first tag from line

   for /F "tokens=1* delims=<" %%a in ("!line!") do (

      set "tag=%%a"

      set "line=%%b"

   )

   rem Show first tag in one separate line

   if "%tag:~0,1%" equ "/" set /A level-=5

   echo !spaces:~0,%level%!^<!tag!

   if "%tag:~0,1%" neq "/" set /A level+=5

if defined line goto nextTag

Output:

<xml>

     <tag>

          <othertag>

          </othertag>

     </tag>

</xml>

Note that the maximum length of a line that can be processed this way is 8150 characters approx. Also, this solution remove any exclamation-marks from the file. Both points can be fixed, if required.

try this :

@echo off



call ::beautifyXml c:some.xml



exit /b %errorlevel%



::::::::::::::::::

:beautifyXml

@echo off

powershell "function fx($xml, $i=2){$SW=New-Object System.IO.StringWriter;$XW=New-Object System.XMl.XmlTextWriter $SW; $XW.Formatting='indented';$XW.Indentation=$i;([xml]$xml).WriteContentTo($XW);$XW.Flush();$SW.Flush();Write-Output $SW.ToString();};FX (gc -path """%~f1""") -i 4">"%~dp1~"

move /y "%~dp1~" "%~f1" >nul 2>nul

goto :eof